%newsas(health);
title 'Suppression effect: Health, Height and Weight';
/*
... wherein height and weight, individually are weakly related
    to health, but together are strongly related
*/
data health;
   input height       weight      health;
	length case $1;
	case = substr('123456789ABCDEFGS',_n_,1);
datalines;
    9.4          6.8        12.0
   11.4         13.7         8.0
   10.4          9.4        12.3
   10.7         12.1         9.4
   11.8         10.0        10.4
    9.1          9.3        11.7
   12.3          7.0        13.9
    7.3         10.2        10.0
   11.2         12.2         9.1
    7.8          8.9         9.1
    6.1          7.5         6.0
   15.0         12.3        13.1
    6.0          3.3        12.8
   19.3         20.7        10.7
   15.3         13.5        14.1
   10.0         10.0        11.0
;
*-- Look at pairwise correlations: Misleading!;
proc corr data=health nosimple noprob;
run;
proc plot data=health hpercent=33 vpercent=33 nolegend;
	plot health*health=' '   health*height=case  health*weight=case
	     height*health=case  height*height=' '   height*weight=case
	     weight*health=case  weight*height=case  weight*weight=' ';
run;
*include goptions;
%scatmat(data=health, var=Health Height Weight, interp=rl);

proc reg data=health;
	var health height weight;
	id case;
	model health = height;
	model health = weight;
	model health = height weight;
	model weight = height;
	   plot health * r. = case;

%partial(data=health, yvar=health, xvar=height weight, id=case, out=partres);