title 'Arthritis treatment data';
*include goptions;
goptions htext=1.7 hsize=7in;
%include data(arthrit);
proc sort;
   by age;
proc logistic nosimple;
   format better outcome.;
   model  better = age ;
   output out=results p=predict l=lower u=upper;
   title2 'Linear and Logit Regressions on Age'; run;
proc gplot;
   plot better * age = 1
        predict * age = 2
        upper * age = 3
        lower * age = 3
        / frame overlay vaxis=axis1;
   axis1 label=(a=90) offset=(3) order=(0 to 1 by .1);
   symbol1 v=circle h=1.7 i=rlclm l=2 c=black ci=red;
   symbol2 v=none   i=join l=1 w=3 c=blue;
   symbol3 v=none   i=join l=20    c=blue;
   label better='Probability (Improved)';
   format better 4.1;
run;
proc logistic nosimple data=arthrit;
   format better outcome.;
   model  better = age _treat_;
   output out=results p=predict l=lower u=upper;
title2 'Logit Regression on Age and Treatment';
proc print;
data points;
   set results;
   retain xsys ysys '2' function 'SYMBOL';
   x = age;
   y = better;
   text='circle';
   if _treat_=0 then color='BLUE';
      else do;
         color='RED ';
         text = 'dot';
     *   y = .98*(y=1) + .02*(y=0);
      end;
   size=1.6;
proc gplot;
   plot predict * age= treat
        / frame vaxis=axis1 anno=points;
   symbol1 v=none i=join w=3 c=blue;
   symbol2 v=none i=join w=3 c=red;
   format better 4.1;
   label treat='Treatment';
run;
%gfinish;