*---------------------------------------------------------------------;
*                   Eight Physical Variables                          ;
* Data from Ph.D. thesis of Mullen(1935), Univ. of Chicago            ;
* Used extensively in Harman's Modern Factor Analysis, 1967           ;
*  The first 4 variables were assumed to measure 'lankiness'          ;
*  the last 4 'stockiness'                                            ;
*---------------------------------------------------------------------;
* The example also illustrates input of a correlation matrix.         ;
*---------------------------------------------------------------------;
 
DATA PHYS8(TYPE=CORR);
TITLE 'Eight physical variables';
TITLE2 'See page 80 of Harman: Modern Factor Analysis, 2nd Ed.';
 
   Length _NAME_ _TYPE_ $8;
   INPUT _NAME_ $ 1-5 _TYPE_ 6-9
         VAR1 11-16 VAR2 17-24 VAR3 25-32 VAR4 33-40
         VAR5 41-48 VAR6 49-56 VAR7 57-64 VAR8 65-72;
   LABEL  VAR1='HEIGHT'
          VAR2='ARM SPAN'
          VAR3='LENGTH OF FOREARM'
          VAR4='LENGTH OF LOWER LEG'
          VAR5='WEIGHT'
          VAR6='BITROCHANTERIC DIAMETER'
          VAR7='CHEST GIRTH'
          VAR8='CHEST WIDTH';
   List;
CARDS;
VAR1 CORR 1.0   .846    .805    .859    .473    .398    .301    .382
VAR2 CORR .846  1.0     .881    .826    .376    .326    .277    .415
VAR3 CORR .805  .881    1.0     .801    .380    .319    .237    .345
VAR4 CORR .859  .826    .801    1.0     .436    .329    .327    .365
VAR5 CORR .473  .376    .380    .436    1.0     .762    .730    .629
VAR6 CORR .398  .326    .319    .329    .762    1.0     .583    .577
VAR7 CORR .301  .277    .237    .327    .730    .583    1.0     .539
VAR8 CORR .382  .415    .345    .365    .629    .577    .539    1.0
     N     305   305     305     305     305     305     305     305
;
/*---------------------------------------------------------------------*/
/*Principal factors using estimated PRIOR communalities. The communal- */
/*ities were estimated assuming the correlation matrix to be of rank 2.*/
/*See Harmon, Table 5.4, p.81                                          */
/*---------------------------------------------------------------------*/
 
PROC FACTOR
        METHOD=PRIN NFACT=2
        OUTSTAT=FACT                    /* Output data set            */
        ROUND                           /* Round loading in printout  */
        RESIDUALS                       /* Print residual correlations*/
        PLOT;
     PRIORS .854 .897 .833 .783 .870 .687 .521 .579;
     Var VAR1-VAR8;
TITLE2 'SEE PP 154-155 of Harman: Modern Factor Analysis, 2nd Ed.';
 
PROC PRINT;
     BY _TYPE_ NOTSORTED;
     Format VAR1-VAR8 8.4;
     Title2 'Output data set from Proc FACTOR';
 
* The rest of the analyses use the OUTSTAT dataset from the first
  analysis. That's OK, since it contains the same correlation matrix
  as _TYPE_ = 'CORR' observations;
 
PROC FACTOR ROTATE=VARIMAX PLOT;
title2 'Varimax rotation:  Harman, page 309';
/*
PROC FACTOR ROTATE=PROMAX PLOT;
TITLE2 'PROMAX ROTATION';
*/
/*-------------------------------------------------------------*/
/*  Minres / Unweighted least squares solution for k=2 factors */
/*-------------------------------------------------------------*/
PROC FACTOR METHOD=ULS NFACT=2;
Title2 'Minres / Unweighted least squares solution k=2';
TITLE3 'See page 205 of Harman: Modern Factor Analysis, 2nd Ed.';
 
/*-----------------------------------------------------------------*/
/*  Now find k=3 factor solutions by ULS & Maximum liklihood. Note */
/*  that the communality of VAR 2 becomes > 1, which is a Heywood  */
/*  case.  The HEYWOOD option causes factor to set the communality */
/*  to 1, and allows the iterations to proceed.                    */
/*-----------------------------------------------------------------*/
/*
PROC FACTOR METHOD=ULS NFACT=3 HEYWOOD;
Title2 'Minres / Unweighted least squares solution k=3';
*/
PROC FACTOR METHOD=ML NFACT=3 HEYWOOD;
Title2 'Maximum liklihood solution k=3';
TITLE2 'See page 228 of Harman: Modern Factor Analysis, 2nd Ed.';
run;