/****************************************************************/
 /*  FACTOR SAS                                                  */
 /*  Factor Analysis for 9 Psychological Variables (Harman)      */
 /****************************************************************/
DATA PSYCH9 (TYPE=CORR DF=696);
   Title 'Nine Psychological Variables:  Harman, page 244';
   INPUT _TYPE_ $1-4 _NAME_ $6-7 X1-X9;
   LABEL
      X1='WORD MEANING'
      X2='SENTENCE COMPOSITION'
      X3='ODD WORDS'
      X4='MIXED ARITHMETIC'
      X5='REMAINDERS'
      X6='MISSING NUMBERS'
      X7='GLOVES'
      X8='BOOTS'
      X9='HATCHETS';
    CARDS;
CORR X1    1.00   .     .     .     .     .     .     .     .
CORR X2     .75  1.00   .     .     .     .     .     .     .
CORR X3     .78   .72  1.00   .     .     .     .     .     .
CORR X4     .44   .52   .47  1.00   .     .     .     .     .
CORR X5     .45   .53   .48   .82  1.00   .     .     .     .
CORR X6     .51   .58   .54   .82   .74  1.00   .     .     .
CORR X7     .21   .23   .28   .33   .37   .35  1.00   .     .
CORR X8     .30   .32   .37   .33   .36   .38   .45  1.00   .
CORR X9     .31   .30   .37   .31   .36   .38   .52   .67  1.00
N          696   696   696   696   696   696   696   696   696
;
PROC PRINT;
 
/*-------------------------------------|
 | PRINCIPAL COMPONENTS ANALYSIS       |
 |-------------------------------------*/
PROC FACTOR;
 
/*-------------------------------------|
 | MAXIMUM LIKLIHOOD FACTOR ANALYSIS   |
 |-------------------------------------*/
PROC FACTOR METHOD=ML NFACT=3 MSA SCREE PREPLOT
     OUTSTAT=FACT;
 
PROC PRINT; ID _TYPE_;
 
/*-------------------------------------|
 | Promax Rotation of ML Factors       |
 |-------------------------------------*/
PROC FACTOR ROTATE=PROMAX NORM=WEIGHT REORDER ROUND FUZZ=.1 PLOT
     OUTSTAT=FACT;
 run;