/*--------------------------------------------------------------
  *
  *                  SAS/STAT TEST LIBRARY
  *
  *       NAME: calis36
  *    SUPPORT: Wolfgang M. Hartmann
  *     UPDATE:
  *  REFERENCE: Six different Kinds of Abilities,
  *             JOERESKOG (1978, pp.475)
  *             Also LISREL VI Manual (1985, p. III.24)
  *       DATA: WARREN, WHITE & FULLER (1978)
  * EVALUATION:
  *   FUNCTION: Two Circumplex Models
  *       MISC:
  *
  --------------------------------------------------------------*/
 
 OPTIONS NODATE LS=120 PS=60;
 
TITLE 'TEST36: Six Different Kinds of Abilties, GUTTMAN (1954)';
TITLE2 'Two Circumplex Models, Joreskog (1978, p.475) LISREL (p.III.24)';
DATA LORD(TYPE=CORR);
   INPUT _TYPE_ $ _NAME_ $ V1-V6;
   label V1='Association'  V2='Incomplete Words' V3='Multiplication'
         V4='Dot patterns' V5='ABC'              V6='Directions';
   CARDS;
CORR V1    1.000      .        .       .       .       .
CORR V2     .446    1.000      .       .       .       .
CORR V3     .321     .388    1.000     .       .       .
CORR V4     .213     .313     .396   1.000     .       .
CORR V5     .234     .208     .325    .352   1.000     .
CORR V6     .442     .330     .328    .247    .347   1.000
MEAN .      0        0        0      0       0       0
STD  .      1        1        1      1       1       1
  ;
PROC CALIS DATA=LORD METHOD=LSMAX TECH=LM EDF=709 short;
 TITLE3 'Test circular correlation pattern: C = D * P * D';
 COSAN  D(6, DIA) * P(6, SYM);
 MATRIX D
           [1,1] = D1-D6 ;
 MATRIX P
           [1, ] = 1. ,
           [2, ] = R1 1. ,
           [3, ] = R2 R1 1. ,
           [4, ] = R3 R2 R1 1. ,
           [5, ] = R2 R3 R2 R1 1. ,
           [6, ] = R1 R2 R3 R2 R1 1. ;
 RUN;
 
PROC CALIS DATA=LORD METHOD=MAX TECH=LM EDF=709 short mod;
 TITLE3 'Test quasi circumplex model: C = D * C * DP * C * D + T';
 COSAN  D(6, DIA) * C(6, GEN) * DP(6, DIA) + T(6, DIA);
 MATRIX D
           [1,1] = D1-D6 ;
 MATRIX DP
           [1,1] = 1. DP1-DP5 ;
 MATRIX C
           [1, ] = 1. 1. 1. 1. 0. 0. ,
           [2, ] = 0. 1. 1. 1. 1. 0. ,
           [3, ] = 0. 0. 1. 1. 1. 1. ,
           [4, ] = 1. 0. 0. 1. 1. 1. ,
           [5, ] = 1. 1. 0. 0. 1. 1. ,
           [6, ] = 1. 1. 1. 0. 0. 1. ;
 MATRIX T
           [1,1] = T1-T6 ;
 RUN;