%newsas(social2);
title 'Social perception of internal-external control';

/*
36 male subjects were shown a photograph of a male or female
and asked to fill out the Rotter Internal-External scale
the way they thought *that person* would fill it out.
(I-E Scale: low scores= Internal locus of control, high
scores= External locus of control.)
Each photograph had previously been classified in terms of
physical attractiveness.

The experiment was repeated with a sample of 36 female sujbects.
*/
data social1;
	subjsex='Male  ';
	input photo $ attract $ @;
	do sub=1 to 6;
		input iescale @;
		output;
		end;
	label attract='Photo attractiveness'
		photo='Sex of photo'
		subjsex='Sex of subject'
		iescale='I-E Scale';
datalines;
Male   1:High   8   8  12   7   8   4
Male   2:Med    9  10   9  13   5   8
Male   3:Low   14   9  11   6  10  10
Female 1:High   6  12   9   9  10   8
Female 2:Med   10   9   6  15  10  11
Female 3:Low   14  13  10  13  12  16
;
data social2;
	subjsex='Female';
	input photo $ attract $ @;
	do sub=1 to 6;
		input iescale @;
		output;
		end;
datalines;
Male   1:High  12   8  10   6   8   4
Male   2:Med    9   7   9   5  11  12
Male   3:Low   10  12   8   6  10  11
Female 1:High   8   7   3   8  12  10
Female 2:Med    7  13   9   9   9  11
Female 3:Low   13  14  19  11  16  14
;
*-- Combine the two data sets;
data social;
	set social1 social2;
	
proc glm data=social;
	class subjsex photo attract;
	model iescale = subjsex | photo | attract / ss3;
	contrast 'Attract-lin' attract  -1  0  1;
	contrast 'Attract-2nd' attract   1 -2  1;
	contrast 'Photo * Attr-lin' photo*attract     -1  0  1   1  0  -1;
	contrast 'Photo * Attr-2nd' photo*attract      1 -2  1  -1  2  -1;
run;

%include goptions;
goptions htext=1.7 htitle=2 hsize=7in vsize=7in;
*meanplot(data=social, class=Attract Photo Subjsex, response=IEScale,
	cmean=no);
%intplot(data=social, class=Attract Photo Subjsex, response=IEScale);