%newsas(infantm);
/*-----------------------------------------------------*
 *  Infant Mortality Rates for Nations of the World    *
 *  -- Transform to equalize spreads                   *
 *-----------------------------------------------------*/
title 'Infant Mortality Rates';
data infantm;
     input country $1-18
           IMR
           region  $27-30;
     label imr='Infant mortality rate';
datalines;
CANADA              16.8  AMER
UNITED STATES       17.6  AMER
ECUADOR             78.5  AMER
VENEZUELA           51.7  AMER
ARGENTINA           59.6  AMER
BRAZIL             170.0  AMER
CHILE               78.0  AMER
COLUMBIA            62.8  AMER
COSTA RICA          54.4  AMER
DOMINICAN REP.      48.8  AMER
GUATEMALA           79.1  AMER
JAMAICA             26.2  AMER
MEXICO              60.9  AMER
NICARAGUA           46.0  AMER
PANAMA              34.1  AMER
PERU                65.1  AMER
URUGUAY             40.4  AMER
BOLIVIA             60.4  AMER
EL SALVADOR         58.2  AMER
HONDURAS            39.3  AMER
PARAGUAY            38.6  AMER
HAITI               .     AMER
TRINIDAD            26.2  AMER
S. AFRICA           71.5  AFRI
ALGERIA             86.3  AFRI
LIBYA              300.0  AFRI
NIGERIA             58.0  AFRI
TUNISIA             76.3  AFRI
ZAMBIA             259.0  AFRI
CAMEROON           137.0  AFRI
CONGO              180.0  AFRI
EGYPT              114.0  AFRI
GHANA               63.7  AFRI
IVORY COAST        138.0  AFRI
LIBERIA            159.2  AFRI
MOROCCO            149.0  AFRI
BURUNDI            150.0  AFRI
C. AFRICAN REP.    190.0  AFRI
CHAD               160.0  AFRI
DAHOMEY            109.0  AFRI
ETHIOPIA            84.2  AFRI
GUINEA             216.0  AFRI
KENYA               55.0  AFRI
MADAGASCAR         102.0  AFRI
MALAWI             148.3  AFRI
MALI               120.0  AFRI
MAURITANIA         187.0  AFRI
NIGER              200.0  AFRI
RWANDA             132.9  AFRI
SIERRA LEONE       170.0  AFRI
SOMALIA            158.0  AFRI
TANZANIA           162.5  AFRI
SUDAN              129.4  AFRI
TOGO               127.0  AFRI
UGANDA             160.0  AFRI
UPPER VOLTA        180.0  AFRI
ZAIRE              104.0  AFRI
AUSTRIA             23.7  EURO
BELGIUM             17.0  EURO
DENMARK             13.5  EURO
FINLAND             10.1  EURO
FRANCE              12.9  EURO
W. GERMANY          20.4  EURO
IRELAND             17.8  EURO
ITALY               25.7  EURO
NETHERLANDS         11.6  EURO
NORWAY              11.3  EURO
PORTUGAL            44.8  EURO
SWEDEN               8.5  EURO
SWITZERLAND         12.8  EURO
BRITAIN             17.5  EURO
GREECE              27.8  EURO
SPAIN               15.1  EURO
YUGOSLAVIA          43.3  EURO
AUSTRALIA           16.7  ASIA
JAPAN               11.7  ASIA
NEW ZEALAND         16.2  ASIA
INDONESIA          125.0  ASIA
IRAN                  .   ASIA
IRAQ                28.1  ASIA
S. ARABIA          650.0  ASIA
ISRAEL              22.1  ASIA
LEBANON             13.6  ASIA
MALAYSIA            32.0  ASIA
SINGAPORE           20.4  ASIA
TAIWAN              19.1  ASIA
JORDAN              21.3  ASIA
S. KOREA            58.0  ASIA
PAPUA               10.2  ASIA
PHILLIPINES         67.9  ASIA
SYRIA               21.7  ASIA
THAILAND            27.0  ASIA
TURKEY             153.0  ASIA
VIETNAM            100.0  ASIA
AFGHANISTAN        400.0  ASIA
BANGLADESH         124.3  ASIA
BURMA              200.0  ASIA
CAMBODIA           100.0  ASIA
INDIA               60.6  ASIA
LAOS                  .   ASIA
NEGAL                 .   ASIA
PAKISTAN           124.3  ASIA
SRI LANKA           45.1  ASIA
S. YEMEN            80.0  ASIA
YEMEN               50.0  ASIA
;
proc print ;
 
*include macros(splot);
%splot(data=infantm, var=IMR, class=region);
 
* Use proc univariate to get median and HSPR values for log-Med
  vs. log-HSPR plot. NOPRINT option suppresses printed output,
  but OUTPUT statement sends results to an output dataset
  PCTLDEF=2 option gives median, quartile values closest to
  definition used in EDA book.  ;
 
proc sort data=INFANTM;     /* proc Univariate BY REGION requires */
     by REGION;             /* data set to be sorted first        */
 
proc univariate data=INFANTM noprint pctldef=2;
     id  COUNTRY;
     by  REGION;
     var IMR;
     output out=SUMRY median=MEDIAN QRANGE=HSPR  n=N;
 
data SUMRY;
     set sumry;
     drop COUNTRY;
     NOTCHWID = 1.58 * HSPR / sqrt(N);
     LONOTCH = MEDIAN - NOTCHWID;
     HINOTCH = MEDIAN + NOTCHWID;
     LOGMED = LOG10(MEDIAN);
     LOGHSPR = LOG10(HSPR);
proc print;
proc Plot data=sumry;        /* poor mans notched boxplot */
     plot median * region = '-'
          lonotch* region = 'v'
          hinotch* region = '^' / overlay;
 
* Determine whether there is a need to transform the data
  to equalize variability;
 
proc Plot data=sumry;
     Plot LOGHSPR * LOGMED = REGION / hpos=60 vpos=50;
 
* Plot shows that log(IMR) will equalize spread;
data Infantm;
     Set Infantm;
     LOGMORT = log10(IMR);
 
%splot(data=infantm, var=logmort, class=region);